home *** CD-ROM | disk | FTP | other *** search
/ Aminet 44 / Aminet 44 (2001)(GTI - Schatztruhe)[!][Aug 2001].iso / Aminet / game / misc / CCGames.lha / BAGELS.BAS < prev    next >
BASIC Source File  |  1980-01-01  |  2KB  |  83 lines
  1. 3 PRINT CHR$(26)
  2. 5 PRINT TAB(33);"BAGELS":PRINT
  3. 10 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY":PRINT:PRINT
  4. 15 REM *** BAGLES NUMBER GUESSING GAME
  5. 20 REM *** ORIGINAL SOURCE UNKNOWN BUT SUSPECTED TO BE
  6. 25 REM *** LAWRENCE HALL OF SCIENCE, U.C. BERKELY
  7. 30 DIM A1(6),A(3),B(3)
  8. 40 Y=0:T=255
  9. 50 PRINT:PRINT:PRINT
  10. 70 INPUT "WOULD YOU LIKE THE RULES (YES OR NO)";A$
  11. 90 IF LEFT$(A$,1)="N" OR LEFT$(A$,1)="n" THEN 150
  12. 100 PRINT:PRINT "I AM THINKING OF A THREE-DIGIT NUMBER.  TRY TO GUESS"
  13. 110 PRINT "MY NUMBER AND I WILL GIVE YOU CLUES AS FOLLOWS:"
  14. 120 PRINT "   PICO   - ONE DIGIT CORRECT BUT IN THE WRONG POSITION"
  15. 130 PRINT "   FERMI  - ONE DIGIT CORRECT AND IN THE RIGHT POSITION"
  16. 140 PRINT "   BAGELS - NO DIGITS CORRECT"
  17. 150 FOR I=1 TO 3
  18. 160 A(I)=INT(10*RND(1))
  19. 165 IF I-1=0 THEN 200
  20. 170 FOR J=1 TO I-1
  21. 180 IF A(I)=A(J) THEN 160
  22. 190 NEXT J
  23. 200 NEXT I
  24. 210 PRINT:PRINT "O.K.  I HAVE A NUMBER IN MIND."
  25. 220 FOR I=1 TO 20
  26. 230 PRINT "GUESS #";I,
  27. 240 INPUT A$
  28. 245 IF LEN(A$)<>3 THEN 630
  29. 250 FOR Z=1 TO 3:A1(Z)=ASC(MID$(A$,Z,1)):NEXT Z
  30. 260 FOR J=1 TO 3
  31. 270 IF A1(J)<48 THEN 300
  32. 280 IF A1(J)>57 THEN 300
  33. 285 B(J)=A1(J)-48
  34. 290 NEXT J
  35. 295 GOTO 320
  36. 300 PRINT "WHAT?"
  37. 310 GOTO 230
  38. 320 IF B(1)=B(2) THEN 650
  39. 330 IF B(2)=B(3) THEN 650
  40. 340 IF B(3)=B(1) THEN 650
  41. 350 C=0:D=0
  42. 360 FOR J=1 TO 2
  43. 370 IF A(J)<>B(J+1) THEN 390
  44. 380 C=C+1
  45. 390 IF A(J+1)<>B(J) THEN 410
  46. 400 C=C+1
  47. 410 NEXT J
  48. 420 IF A(1)<>B(3) THEN 440
  49. 430 C=C+1
  50. 440 IF A(3)<>B(1) THEN 460
  51. 450 C=C+1
  52. 460 FOR J=1 TO 3
  53. 470 IF A(J)<>B(J) THEN 490
  54. 480 D=D+1
  55. 490 NEXT J
  56. 500 IF D=3 THEN 680
  57. 505 IF C=0 THEN 545
  58. 520 FOR J=1 TO C
  59. 530 PRINT "PICO ";
  60. 540 NEXT J
  61. 545 IF D=0 THEN 580
  62. 550 FOR J=1 TO D
  63. 560 PRINT "FERMI ";
  64. 570 NEXT J
  65. 580 IF C+D<>0 THEN 600
  66. 590 PRINT "BAGELS";
  67. 600 PRINT
  68. 605 NEXT I
  69. 610 PRINT "OH WELL."
  70. 615 PRINT "THAT'S TWNETY GUESSES.  MY NUMBER WAS";100*A(1)+10*A(2)+A(3)
  71. 620 GOTO 700
  72. 630 PRINT "TRY GUESSING A THREE-DIGIT NUMBER.":GOTO 230
  73. 650 PRINT "OH, I FORGOT TO TELL YOU THAT THE NUMBER I HAVE IN MIND"
  74. 660 PRINT "HAS NO TWO DIGITS THE SAME.":GOTO 230
  75. 680 PRINT "YOU GOT IT!!!":PRINT
  76. 690 Y=Y+1
  77. 700 INPUT "PLAY AGAIN (YES OR NO)";A$
  78. 720 IF LEFT$(A$,1)="Y" OR LEFT$(A$,1)="y" THEN 150
  79. 730 IF Y=0 THEN 750
  80. 740 PRINT:PRINT "A";Y;"POINT BAGELS BUFF!!"
  81. 750 PRINT "HOPE YOU HAD FUN.  BYE."
  82. 999 RUN "MENU"
  83.